1 DISK$="DSK1.BBCFILE"
2 CALL CHAR(61,"0000FF0000FF")
3 CALL CHAR(97,"00000038043C443C00004040784444780000003C4040403C")
4 CALL CHAR(100,"000004043C44443C00000038447C403800000C103C1010100000003C443C0438")
5 CALL CHAR(104,"000040407844444400001000301010380000040004040438000040405860504C")
6 CALL CHAR(108,"0000301010101038000000685454545400000078444444440000003844444438")
7 CALL CHAR(112,"00000078444478400000003C44443C0400000078444040400000003C40380478")
8 CALL CHAR(116,"0000107C1010100C000000444444443C00000044444428100000004454545428")
9 CALL CHAR(120,"000000442810284400000044443C04380000007C0810207C")
10 CALL CLEAR
11 CALL CHAR(123,"80808080808080FF")
12 CALL CHAR(125,"01010101010101FF")
13 CALL CHAR(47,"0102040810204080")
14 CALL CHAR(92,"8040201008040201")
15 REM v1.2.2 "Lynn"
16 PRINT "/\"
17 PRINT "{} Home Plate"
20 PRINT "Baseball Card DB v1.2.2"
25 PRINT
30 PRINT "Active Data File is ",DISK$
40 PRINT "==========================="
100 PRINT "[A] Enter Card"
110 PRINT "[L] List Card(s) By Search"
120 PRINT "[S] Set Disk Read/Write"
125 PRINT "[s] See Current Disk"
130 PRINT "[X] Exit"
135 PRINT "==========================="
150 INPUT CH$
160 IF CH$ = "A" THEN 190
170 IF CH$ = "L" THEN 300
175 IF CH$ = "S" THEN 1100
176 IF CH$ = "s" THEN 1600
179 IF CH$ = "X" THEN 2000
180 PRINT "INVALID OPTION - Press Enter"
182 INPUT ENTER$
185 GOTO 10
190 PRINT "ENTER *Name* ON CARD:"
200 INPUT NAME$
205 PRINT "ENTER CARD *Brand*:"
210 INPUT BRND$
215 PRINT "ENTER *Year* OF CARD:"
220 INPUT YEAR$
225 PRINT "ENTER CARD *Number*:"
230 INPUT CDNO$
232 PRINT "ENTER CARD *Condition*:"
233 PRINT "M=Mint/NM=NearMint"::PRINT "EX=Excellent/VG=VeryGood"
234 PRINT "G=Good/F=Fair/P=Poor" 
235 INPUT COND$
236 PRINT "ENTER OneWord Note(max 12 char)"
237 PRINT "Example 1: ErrorCard"
238 PRINT "Example 2: GreenFoil"
239 INPUT NOTE$
240 OPEN #1:DISK$,SEQUENTIAL,DISPLAY,APPEND,VARIABLE
250 PRINT #1:NAME$,BRND$,YEAR$,CDNO$,COND$,NOTE$
260 CLOSE #1
270 PRINT "Data written to ",DISK$
290 GOTO 10
300 PRINT "INPUT Name on card TO LIST"
305 PRINT " (Case Sensitive)"
310 INPUT LNAM$
500 OPEN #1:DISK$,SEQUENTIAL,DISPLAY,INPUT,VARIABLE
510 IF EOF(1) THEN 550
515 INPUT #1:A$
517 P = POS(A$, LNAM$, 1)
520 IF P > 0 THEN 530 ELSE 540
530 PRINT A$
535 PRINT "==========================="
536 PAGE=PAGE+1
537 if PAGE=3 THEN GOSUB 1500
540 GOTO 510
550 CLOSE #1
560 PRINT "Screen Print Done"
565 PRINT " - Press Enter"
570 INPUT ENTER$
1000 GOTO 10
1100 CALL CLEAR
1120 PRINT "Baseball Card DB v1.2"
1122 PRINT "Set Disk Read/Write"
1125 PRINT "=========================="
1130 PRINT "[A] Disk 1 (DSK1)"
1140 PRINT "[B] Disk 2 (DSK2)"
1150 PRINT "[C] Disk 3 (DSK3)"
1160 INPUT CH$
1170 IF CH$ = "A" THEN DISK$="DSK1.BBCFILE"
1180 IF CH$ = "B" THEN DISK$="DSK2.BBCFILE"
1190 IF CH$ = "C" THEN DISK$="DSK3.BBCFILE"
1196 GOTO 10
1500 PRINT "Paused - Press Enter"
1505 INPUT ENTER$
1510 PAGE = 0
1520 RETURN

1600 CALL CLEAR
1610 COUNT=0
1620 DIM TYPE$(6)
1630 TYPE$(1)="DIS/FIX"
1640 TYPE$(2)="DIS/VAR"
1650 TYPE$(3)="INT/FIX"
1660 TYPE$(4)="INT/VAR"
1670 TYPE$(5)="PROGRAM"
1680 TYPE$(6)=" <DIR> "

1700 IF DISK$="DSK1.BBCFILE" THEN DISK$="DSK1."
1702 IF DISK$="DSK2.BBCFILE" THEN DISK$="DSK2."
1704 IF DISK$="DSK3.BBCFILE" THEN DISK$="DSK3."

1710 REM  THIS OPENS AS IF/0 - WHICH BECOMES IF/38 
1720 OPEN #1:DISK$,INPUT,RELATIVE,INTERNAL

1740 INPUT #1:DISKNAME$,ZERO,DISKSECTORS,FREESECTORS
1750 DISPLAY "DSK0 -  DISKNAME= ";DISKNAME$:"AVAILABLE= ";FREESECTORS;" USED= ";DISKSECTORS-FREESECTORS
1760 DISPLAY :"FILENAME   SIZE    TYPE    P":"---------- ---- ---------- -";

1770 REM  A FILETYPE OF 0 ALSO MEANS END OF DIRECTORY 
1780 REM  FILETYPE IS NEGATIVE FOR A PROTECTED FILE 
1790 INPUT #1:FILENAME$,FILETYPE,FILESECTORS,RECORDLENGTH
1800 IF LEN(FILENAME$)=0 THEN 1885

1820 DISPLAY :FILENAME$;TAB(12);FILESECTORS;TAB(17);TYPE$(ABS(FILETYPE));
1830 REM  PROGRAM FILES DON'T HAVE A RECORD LENGTH 
1840 IF ABS(FILETYPE)>=5 THEN 1870
1850 B$=" "&STR$(RECORDLENGTH)
1860 DISPLAY SEG$(B$,LEN(B$)-2,3);
1870 IF FILETYPE>0 THEN 1790
1875 DISPLAY TAB(28);"Y";
1880 GOTO 1790
1885 CLOSE #1
1890 IF DISK$="DSK1." THEN DISK$="DSK1.BBCFILE"
1892 IF DISK$="DSK2." THEN DISK$="DSK2.BBCFILE"
1894 IF DISK$="DSK3." THEN DISK$="DSK3.BBCFILE"
1896 PRINT "PRESS Enter"::INPUT ENTER$
1899 GOTO 10
2000 END